Add tasks to update esbuild version

lib/mix/tasks/esbuild/check_version.ex

@@ -0,0 +1,28 @@
+defmodule Mix.Tasks.Esbuild.CheckVersion do
+  use Mix.Task
+
+  @shortdoc "Checks the the current Esbuild version is the latest"
+  @moduledoc """
+  Checks the the current esbuild version is the latest.
+
+  Exits with 0 if versions match, 1 if the esbuild needs to be updated.
+  """
+
+  alias Mix.Tasks.Esbuild.Release
+
+  @impl Mix.Task
+  def run(_args) do
+    current_version = Release.fetch_current_version()
+    latest_version = Release.fetch_latest_version!()
+
+    if current_version !== latest_version do
+      Mix.Shell.IO.info(
+        "A new esbuild version is available: #{current_version} ==> #{latest_version}"
+      )
+
+      System.halt(1)
+    else
+      Mix.Shell.IO.info("The esbuild version is up to date (#{current_version})")
+    end
+  end
+end

lib/mix/tasks/esbuild/release.ex

@@ -0,0 +1,27 @@
+defmodule Mix.Tasks.Esbuild.Release do
+  @latest_version_url "https://api.github.com/repos/evanw/esbuild/releases/latest"
+
+  def fetch_latest_version! do
+    Application.ensure_all_started(:req)
+
+    Req.get!(@latest_version_url).body["tag_name"]
+    |> String.replace_prefix("v", "")
+  end
+
+  def fetch_current_version do
+    Application.get_env(:esbuild, :version)
+  end
+
+  def update_config_file!(config_file, current_version, latest_version) do
+    config_contents = File.read!(config_file)
+
+    new_config_contents =
+      String.replace(
+        config_contents,
+        ~s(version: "#{current_version}"),
+        "version: \"#{latest_version}\""
+      )
+
+    File.write!(config_file, new_config_contents)
+  end
+end

lib/mix/tasks/esbuild/update_version.ex

@@ -0,0 +1,29 @@
+defmodule Mix.Tasks.Esbuild.UpdateVersion do
+  use Mix.Task
+
+  @shortdoc "Update the configured esbuild versino to latest."
+  @moduledoc """
+  Update the configured esbuild versino to latest.
+  """
+
+  alias Mix.Tasks.Esbuild.Release
+
+  @impl Mix.Task
+  def run(_args) do
+    current_version = Release.fetch_current_version()
+    latest_version = Release.fetch_latest_version!()
+
+    if current_version !== latest_version do
+      Mix.Shell.IO.info(
+        "Updating esbuild configuration from #{current_version} to #{latest_version}"
+      )
+
+      config_file =
+        Path.expand("config/config.exs", File.cwd!())
+
+      Release.update_config_file!(config_file, current_version, latest_version)
+    else
+      Mix.Shell.IO.info("esbuild configuration is up to date (#{current_version})")
+    end
+  end
+end