Extract shared index logic into LiveHelpers.IndexActions

Closes #150
2026-04-13 23:09:22 +01:00
parent 4fa13d5422
commit e43bccb9bc
6 changed files with 223 additions and 218 deletions
@@ -0,0 +1,162 @@
+defmodule MusicLibraryWeb.LiveHelpers.IndexActions do
+  @moduledoc false
+
+  import LiveToast, only: [put_toast: 3]
+  import Phoenix.Component, only: [assign: 3]
+  import Phoenix.LiveView, only: [push_patch: 2, push_navigate: 2, stream: 4, stream_delete: 3]
+  import MusicLibraryWeb.Components.Pagination, only: [page_to_offset: 2]
+  import MusicLibraryWeb.LiveHelpers.Params
+
+  use Gettext, backend: MusicLibraryWeb.Gettext
+
+  alias MusicLibrary.Records
+  alias MusicLibraryWeb.ErrorMessages
+
+  @doc """
+  Applies the :index action. Reads config from `socket.assigns.index_config`
+  for context_module, default_order, allowed_orders, and default_records_list_params.
+
+  Returns the socket (not wrapped in `{:noreply, ...}`).
+  """
+  def apply_index_action(socket, params) do
+    config = socket.assigns.index_config
+
+    query = params["query"] || ""
+    order = parse_order(params["order"] || config.default_order, config.allowed_orders)
+    total_records = config.context_module.search_records_count(query)
+
+    record_list_params =
+      config.default_records_list_params
+      |> merge_query(query)
+      |> merge_order(order)
+      |> merge_pagination(params, total_records)
+
+    load_and_assign_records(socket, record_list_params)
+  end
+
+  @doc """
+  Applies the :import action. Falls back to :index if the stream hasn't
+  been initialized yet.
+
+  Returns the socket (not wrapped in `{:noreply, ...}`).
+  """
+  def apply_import_action(socket, params) do
+    config = socket.assigns.index_config
+    import_query = params["import_query"] || ""
+
+    socket
+    |> apply_fallback_index(params, :records, fn s, :index, p -> apply_index_action(s, p) end)
+    |> assign(:page_title, config.import_page_title)
+    |> assign(:import_query, import_query)
+    |> assign(:record, nil)
+  end
+
+  @doc """
+  Applies the :edit action. Falls back to :index if the stream hasn't
+  been initialized yet.
+
+  Returns the socket (not wrapped in `{:noreply, ...}`).
+  """
+  def apply_edit_action(socket, %{"id" => id} = params) do
+    config = socket.assigns.index_config
+    record = Records.get_record!(id)
+
+    socket
+    |> apply_fallback_index(params, :records, fn s, :index, p -> apply_index_action(s, p) end)
+    |> assign(:page_title, record_page_title(record, config))
+    |> assign(:record, record)
+  end
+
+  @doc """
+  Loads records from the context module and assigns them to the socket stream.
+
+  Returns the socket (not wrapped in `{:noreply, ...}`).
+  """
+  def load_and_assign_records(socket, record_list_params) do
+    config = socket.assigns.index_config
+    offset = page_to_offset(record_list_params.page, record_list_params.page_size)
+
+    records =
+      config.context_module.search_records(record_list_params.query,
+        limit: record_list_params.page_size,
+        offset: offset,
+        order: record_list_params.order
+      )
+
+    socket
+    |> assign(:page_title, config.section_page_title)
+    |> assign(:record, nil)
+    |> assign(:record_list_params, record_list_params)
+    |> stream(:records, records, reset: true)
+  end
+
+  def handle_delete(socket, id) do
+    record = Records.get_record!(id)
+    {:ok, _} = Records.delete_record(record)
+
+    {:noreply, stream_delete(socket, :records, record)}
+  end
+
+  def handle_search(socket, query) do
+    config = socket.assigns.index_config
+
+    qs =
+      config.default_records_list_params
+      |> Map.put(:query, query)
+      |> Map.take([:query, :page, :page_size])
+
+    {:noreply, push_patch(socket, to: config.index_path_fn.(qs))}
+  end
+
+  def handle_import(socket, musicbrainz_id, format) do
+    config = socket.assigns.index_config
+
+    case Records.import_from_musicbrainz_release_group(musicbrainz_id,
+           format: format,
+           purchased_at: config.purchased_at_fn.()
+         ) do
+      {:ok, record} ->
+        {:noreply,
+         socket
+         |> put_toast(:info, config.import_success_toast)
+         |> push_navigate(to: config.record_path_fn.(record.id))}
+
+      {:error, reason} ->
+        {:noreply,
+         socket
+         |> put_toast(
+           :error,
+           config.import_error_toast <> ": " <> ErrorMessages.friendly_message(reason)
+         )
+         |> push_patch(to: config.base_index_path)}
+    end
+  end
+
+  def handle_set_display(socket, mode) do
+    mode = parse_mode(mode)
+
+    {:noreply,
+     socket
+     |> assign(:display, mode)
+     |> load_and_assign_records(socket.assigns.record_list_params)}
+  end
+
+  def handle_record_saved(socket) do
+    {:noreply, load_and_assign_records(socket, socket.assigns.record_list_params)}
+  end
+
+  defp record_page_title(record, config) do
+    Enum.join(
+      [
+        Records.Record.artist_names(record),
+        "-",
+        record.title,
+        "·",
+        gettext("Edit"),
+        "·",
+        config.section_page_title
+      ],
+      " "
+    )
+  end
+end